MRTKのWireFrameShaderを覗いてみる。　Propetiesブロック

本日はShaderおよびMRTKの勉強枠です。

HoloLensの開発ツールであるMRTKではHoloLensアプリで使用できる様々なツールを提供しています。

WireFrameShaderはHoloLensのSpatialAwareness（空間認識）によって生成されるSpatialMeshにdefaultで使用されるShaderになります。

WireFrameShaerはその名のように生成されるSpatialMeshの縁のみを描画します。

〇Propertiesブロック

Propertiesブロックではマテリアル側で設定できる変数を定義します。

 Properties
    {
        // Advanced options.
        [Enum(RenderingMode)] _Mode("Rendering Mode", Float) = 0                                     // "Opaque"
        [Enum(CustomRenderingMode)] _CustomMode("Mode", Float) = 0                                   // "Opaque"
        [Enum(UnityEngine.Rendering.BlendMode)] _SrcBlend("Source Blend", Float) = 1                 // "One"
        [Enum(UnityEngine.Rendering.BlendMode)] _DstBlend("Destination Blend", Float) = 0            // "Zero"
        [Enum(UnityEngine.Rendering.BlendOp)] _BlendOp("Blend Operation", Float) = 0                 // "Add"
        [Enum(UnityEngine.Rendering.CompareFunction)] _ZTest("Depth Test", Float) = 4                // "LessEqual"
        [Enum(DepthWrite)] _ZWrite("Depth Write", Float) = 1                                         // "On"
        _ZOffsetFactor("Depth Offset Factor", Float) = 0                                             // "Zero"
        _ZOffsetUnits("Depth Offset Units", Float) = 0                                               // "Zero"
        [Enum(UnityEngine.Rendering.ColorWriteMask)] _ColorWriteMask("Color Write Mask", Float) = 15 // "All"
        [Enum(UnityEngine.Rendering.CullMode)] _CullMode("Cull Mode", Float) = 2                     // "Back"
        _RenderQueueOverride("Render Queue Override", Range(-1.0, 5000)) = -1

        _BaseColor("Base color", Color) = (0.0, 0.0, 0.0, 1.0)
        _WireColor("Wire color", Color) = (1.0, 1.0, 1.0, 1.0)
        _WireThickness("Wire thickness", Range(0, 800)) = 100
    }

〇レンダリングモード

レンダリングモードはその名の通りオブジェクトの描画に関するモードです。

WireFrameShaderでは次のように定義されています。

  [Enum(RenderingMode)] _Mode("Rendering Mode", Float) = 0   

このShaderは[Microsoft.MixedReality.Toolkit.Editor.MixedRealityWireframeShaderGUI]スクリプトでUnity上で表示されます。

この[Enum(RenderingMode)]はMixedRealityWireframeShaderGUIの中で次の様に定義されています。

 protected enum RenderingMode
        {
            Opaque = 0,
            Cutout = 1,
            Fade = 2,
            Transparent = 3,
            Additive = 4,
            Custom = 5
        }

デフォルトの状態では0が指定されているため[Opaque(不透明)]が適応されます。

〇カスタムレンダリングモード

カスタムレンダリングモードはPropetiesブロックに存在しているもののコード内部では使用されていないようです。

 [Enum(CustomRenderingMode)] _CustomMode("Mode", Float) = 0    

MixedRealityWireframeShaderGUIを見てみてもOpaqueを代入すること以外使用されていないようです。

〇Blending

Blendingは透明度を持つマテリアルの表現で使用されます。　描画の処理の合成にかかわるものです。

これには[ブレンド操作][ブレンド係数]のプロパティがあります。

        [Enum(UnityEngine.Rendering.BlendMode)] _SrcBlend("Source Blend", Float) = 1                 // "One"
        [Enum(UnityEngine.Rendering.BlendMode)] _DstBlend("Destination Blend", Float) = 0            // "Zero"
        [Enum(UnityEngine.Rendering.BlendOp)] _BlendOp("Blend Operation", Float) = 0                 // "Add"

こちらはUnityEngine.Rendering.BlendModeからレンダリングモードを選択しています。　

デフォルトの場合 One Zero Addとなりこれは、出力される処理の色を削除したものにソースとなるものを加算します。

〇ZTest

ZTestとは深度（距離）が異なる二つのピクセルが重なっている場合どちらを出力するかの設定になります。

        [Enum(UnityEngine.Rendering.CompareFunction)] _ZTest("Depth Test", Float) = 4                // "LessEqual"

デフォルトでは[LessEqual]が適応されます。　これは私たちが現実世界のものを見ているように遠くにある順で描画され、私たちの目には近い順重なって見えます。

〇ZWrite

ZWriteは深度情報を書き込むかという設定です。　こちらも透明度を持つオブジェクトで使用されるものです。

 [Enum(DepthWrite)] _ZWrite("Depth Write", Float) = 1                                         // "On"

ZWriteOn にすることで深度情報が使用されます。

〇ZOffsetFactor、ZOffsetUnits

深度情報の設定です。

Factor は、ポリゴンの X または Y に基づいて Z 傾斜の最大値を増減します。つまり深度情報を実際のものとずらし見せかけることができるようです。

Units は、最小の処理できるデプスバッファ値を増減します。これを用いて同一距離にあるはずのオブジェクトの見た目上の距離感を変えることができるようです。

     _ZOffsetFactor("Depth Offset Factor", Float) = 0                                             // "Zero"
        _ZOffsetUnits("Depth Offset Units", Float) = 0                                               // "Zero"

デフォルトではどちらも０になっています。（使用していない）

docs.unity3d.com

〇Cullモード

Cullモードは描画の方向で、通常ポリゴンには法線に沿って表と裏があり、片方に描画が行われますが、その設定になります。

        [Enum(UnityEngine.Rendering.CullMode)] _CullMode("Cull Mode", Float) = 2    Back

デフォルトでBackが使用されています。　つまりメッシュの裏面は描画が行われません。

〇レンダリングキュー

レンダリングキューとは描画順にかかわる設定です。　例えばあるオブジェクトは常に最前面に配置したい。といった場合に使用します。

_RenderQueueOverride("Render Queue Override", Range(-1.0, 5000)) = -1

デフォルトで-1 つまりレンダーキューは２０００が使用されます。

〇その他設定

これまでの設定はShaderそのものの設定でした。

    _BaseColor("Base color", Color) = (0.0, 0.0, 0.0, 1.0)
        _WireColor("Wire color", Color) = (1.0, 1.0, 1.0, 1.0)
        _WireThickness("Wire thickness", Range(0, 800)) = 100

WireframeShaderではベースカラーとワイヤーフレームのカラー、そしてあいまいさを設定できます。　この３つがWireFrameShaderの独自の設定と言えます。

今回はPropetyiesブロックを見ていきました。

次回以降続きを見ていきます。

〇WireFrameShader

// Copyright (c) Microsoft Corporation.
// Licensed under the MIT License.

///
/// Basic wireframe shader that can be used for rendering spatial mapping meshes.
///
Shader "Mixed Reality Toolkit/Wireframe"
{
    Properties
    {
        // Advanced options.
        [Enum(RenderingMode)] _Mode("Rendering Mode", Float) = 0                                     // "Opaque"
        [Enum(CustomRenderingMode)] _CustomMode("Mode", Float) = 0                                   // "Opaque"
        [Enum(UnityEngine.Rendering.BlendMode)] _SrcBlend("Source Blend", Float) = 1                 // "One"
        [Enum(UnityEngine.Rendering.BlendMode)] _DstBlend("Destination Blend", Float) = 0            // "Zero"
        [Enum(UnityEngine.Rendering.BlendOp)] _BlendOp("Blend Operation", Float) = 0                 // "Add"
        [Enum(UnityEngine.Rendering.CompareFunction)] _ZTest("Depth Test", Float) = 4                // "LessEqual"
        [Enum(DepthWrite)] _ZWrite("Depth Write", Float) = 1                                         // "On"
        _ZOffsetFactor("Depth Offset Factor", Float) = 0                                             // "Zero"
        _ZOffsetUnits("Depth Offset Units", Float) = 0                                               // "Zero"
        [Enum(UnityEngine.Rendering.ColorWriteMask)] _ColorWriteMask("Color Write Mask", Float) = 15 // "All"
        [Enum(UnityEngine.Rendering.CullMode)] _CullMode("Cull Mode", Float) = 2                     // "Back"
        _RenderQueueOverride("Render Queue Override", Range(-1.0, 5000)) = -1

        _BaseColor("Base color", Color) = (0.0, 0.0, 0.0, 1.0)
        _WireColor("Wire color", Color) = (1.0, 1.0, 1.0, 1.0)
        _WireThickness("Wire thickness", Range(0, 800)) = 100
    }
    SubShader
    {
        Tags { "RenderType" = "Opaque" }
        Blend[_SrcBlend][_DstBlend]
        BlendOp[_BlendOp]
        ZTest[_ZTest]
        ZWrite[_ZWrite]
        Cull[_CullMode]
        Offset[_ZOffsetFactor],[_ZOffsetUnits]
        ColorMask[_ColorWriteMask]

        Pass
        {
            Offset 50, 100

            CGPROGRAM
            #pragma vertex vert
            #pragma geometry geom
            #pragma fragment frag

            #if defined(SHADER_API_D3D11)
            #pragma target 5.0
            #endif

            #include "UnityCG.cginc"

            float4 _BaseColor;
            float4 _WireColor;
            float _WireThickness;

            // Based on approach described in Shader-Based Wireframe Drawing (2008)
            // http://orbit.dtu.dk/en/publications/id(13e2122d-bec7-48de-beca-03ce6ea1c3f1).html

            struct v2g
            {
                float4 viewPos : SV_POSITION;
                UNITY_VERTEX_OUTPUT_STEREO
            };

            v2g vert(appdata_base v)
            {
                UNITY_SETUP_INSTANCE_ID(v);
                v2g o;
                o.viewPos = UnityObjectToClipPos(v.vertex);
                UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(o);
                return o;
            }

            // inverseW is to counteract the effect of perspective-correct interpolation so that the lines
            // look the same thickness regardless of their depth in the scene.
            struct g2f
            {
                float4 viewPos : SV_POSITION;
                float inverseW : TEXCOORD0;
                float3 dist : TEXCOORD1;
                UNITY_VERTEX_OUTPUT_STEREO
            };

            [maxvertexcount(3)]
            void geom(triangle v2g i[3], inout TriangleStream<g2f> triStream)
            {
                // Calculate the vectors that define the triangle from the input points.
                float2 point0 = i[0].viewPos.xy / i[0].viewPos.w;
                float2 point1 = i[1].viewPos.xy / i[1].viewPos.w;
                float2 point2 = i[2].viewPos.xy / i[2].viewPos.w;

                // Calculate the area of the triangle.
                float2 vector0 = point2 - point1;
                float2 vector1 = point2 - point0;
                float2 vector2 = point1 - point0;
                float area = abs(vector1.x * vector2.y - vector1.y * vector2.x);

                float3 distScale[3];
                distScale[0] = float3(area / length(vector0), 0, 0);
                distScale[1] = float3(0, area / length(vector1), 0);
                distScale[2] = float3(0, 0, area / length(vector2));

                float wireScale = 800 - _WireThickness;

                // Output each original vertex with its distance to the opposing line defined
                // by the other two vertices.
                g2f o;
                UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(o);

                [unroll]
                for (uint idx = 0; idx < 3; ++idx)
                {
                   o.viewPos = i[idx].viewPos;
                   o.inverseW = 1.0 / o.viewPos.w;
                   o.dist = distScale[idx] * o.viewPos.w * wireScale;
                   UNITY_TRANSFER_VERTEX_OUTPUT_STEREO(i[idx], o);
                   triStream.Append(o);
                }
            }

            float4 frag(g2f i) : COLOR
            {
                // Calculate  minimum distance to one of the triangle lines, making sure to correct
                // for perspective-correct interpolation.
                float dist = min(i.dist[0], min(i.dist[1], i.dist[2])) * i.inverseW;

                // Make the intensity of the line very bright along the triangle edges but fall-off very
                // quickly.
                float I = exp2(-2 * dist * dist);

                return I * _WireColor + (1 - I) * _BaseColor;
            }
            ENDCG
        }
    }

    FallBack "Mixed Reality Toolkit/Standard"
    CustomEditor "Microsoft.MixedReality.Toolkit.Editor.MixedRealityWireframeShaderGUI"
}