（保障無しの自己責任で）　　tab5_nixie_flip_clock_V3.zip

　➂ニキシー管／パタパタ時計の選択は、下記の部分を修正してコンパイル＆
　　書き込みます。

　④2025/5/31追記
　　又は、loopの最後の部分「disp_colon(0)」の後112行に下記を追記すれば10分毎に
　　ニキシー管／パタパタ時計を交互に表示出来ます。

　⑤IDEの設定(下記を選択して書き込みます。)



　


４．このあと、TAB5のデモに戻すには下記を参照して戻す事が出来ます。
　TAB5工場出荷時のデモに戻す方法

　

　（保障無しの自己責任で）　　m5stickcp_sindokei.ino

５．動作状況
　①リセット後安定するまで
　

　②起動直後、安定した状態
　

　➂試験的に振動を与えた時（２．４）
　

　④試験的に振動を与えた時（１．１）
　

　⑤２分後に輝度を落とした状態
　


以上

　---------------------------------------------------------------------------------------------------------------

　---------------------------------------------------------------------------------------------------------------




　

　

　




３．「2024/06/20」にLCDが到着したので交換しました。
　①交換前
　

　②LCDのフラットケーブルの外し方
　

　➂交換後の新旧LCD
　

　④LCD交換後、確認の為ファクトリーテストを書き込み見事LCDが復活しました。
　

　⑤組み込んだ後の最後の確認。めでたしめでたし。
　

//atoms3_efont.ino
//V2024/04/17 by JK1VCK
//blog URL:http://gijin77.blog.jp/archives/40506691.html

#include <M5AtomS3.h>
#include "efontEnableJaMini.h"
//#include "efontEnableJa.h"
#include "efont.h"

//#define EFONT_DEBUG
#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels

//efont 文字列を表示する
//**********************************************************************************************
void printEfont(int16_t x,int16_t y,int16_t txtsize,uint16_t color,uint16_t bgcolor,char *str) {
  int posX = x;
  int posY = y;
  int16_t textsize = txtsize;
  uint16_t textcolor = color;
  uint16_t textbgcolor = bgcolor;
  byte font[32];
  while( *str != 0x00 ){
    // 改行処理
    if( *str == '\n' ){
      // 改行
      posY += 16 * textsize;
      posX += 16 * textsize;
      str++;
      continue;
    }
    // フォント取得
    uint16_t strUTF16;
    str = efontUFT8toUTF16( &strUTF16, str );
    getefontData( font, strUTF16 );
    // 文字横幅
    int width = 16 * textsize;
    if( strUTF16 < 0x0100 ){
      // 半角
      width = 8 * textsize;
    }

#ifdef EFONT_DEBUG
    Serial.printf( "str : U+%04X\n", strUTF16 );
#endif

    // 背景塗りつぶし
    M5.Lcd.fillRect(posX, posY, width, 16 * textsize, textbgcolor);
    // 取得フォントの確認
    for (uint8_t row = 0; row < 16; row++) {
      word fontdata = font[row*2] * 256 + font[row*2+1];
      for (uint8_t col = 0; col < 16; col++) {

#ifdef EFONT_DEBUG
        Serial.write( ( (0x8000 >> col) & fontdata ) ? "#" : " " );
#endif

        if( (0x8000 >> col) & fontdata ){
          int drawX = posX + col * textsize;
          int drawY = posY + row * textsize;
          if( textsize == 1 ){
            M5.Lcd.drawPixel(drawX, drawY, textcolor);
          } else {
            M5.Lcd.fillRect(drawX, drawY, textsize, textsize, textcolor);
          }
        }
      }

#ifdef EFONT_DEBUG
        Serial.write( "\n" );
#endif

    }
    // 描画カーソルを進める
    posX += width;
    // 折返し処理
    if( SCREEN_WIDTH <= posX ){ 
      posX = 0;
      posY += 16 * textsize;
    }
  }
  // カーソルを更新
  M5.Lcd.setCursor(posX, posY);
}

void setup() {
auto cfg = M5.config();
  M5.begin(cfg);
  Serial.begin(115200); // シリアル通信初期設定
  delay(1000);        // シリアル接続待ち
  Serial.println("AtomS3 eFont Test!"); // シリアル出力
  M5.Lcd.setRotation( 3 );
  M5.Lcd.clear();
}

void loop() {
  M5.Lcd.clear();
  printEfont(1,10,1,GREEN, BLACK,(char *)"1倍角 こんにちは");
  printEfont(1,28,1,GREEN, BLACK,(char *)"ABCDEFGHIJKLMNOPQRSTUVWXYZ123456");
  delay(5000);
  M5.Lcd.clear();  
  printEfont(1,1,2,GREEN, BLACK,(char *)"2倍角 こんにちは");
  delay(5000);
  M5.Lcd.clear();  
  printEfont(1,1,3,GREEN, BLACK,(char *)"3倍角 こんにちは");
  delay(5000);
}

　

　
　

//atoms3_usb_host_keybord_to_i2c.ino v20230706
//http://gijin77.blog.jp/archives/37426889.html
//USBキーボードをカードキーボードに変換(CardKB v1.1)

#include <M5AtomS3.h>
#include "EspUsbHost.h"
#include <Wire.h>

#define SDA_PIN 2 
#define SCL_PIN 1

uint8_t keyPressed=0;
uint8_t KEY=0;

class MyEspUsbHost : public EspUsbHost {
  void onKeyboardKey(uint8_t ascii, uint8_t keycode, uint8_t modifier) {
    KEY=ascii;keyPressed=1;
    if (' ' <= ascii && ascii <= '~') {
      M5.Lcd.printf("%c", ascii);
    } else if (ascii == '\r') {
      M5.Lcd.println();
    }
  };
};

MyEspUsbHost usbHost;

void requestEvent() {
  if (keyPressed == 1) {
    Wire.write(KEY);
    keyPressed = 0;
  } else {
    Wire.write(0);
  }
}


void setup() {
  M5.begin(true, false, false, false);  // Init M5AtomS3
  M5.Lcd.setRotation( 3 );
  M5.Lcd.clear();
  M5.Lcd.setTextSize(2);
  M5.Lcd.println("EspUsbHostKeybord to I2C" );

  usbHost.begin();
  usbHost.setHIDLocal(HID_LOCAL_Japan_Katakana);

  Wire.onRequest(requestEvent);
  Wire.setPins(SDA_PIN, SCL_PIN);
  Wire.begin(0x5f);

}

void loop() {
  M5.update();  // Read the press state of the key
  if (M5.Btn.wasReleased() || M5.Btn.pressedFor(1000)) {
    M5.Lcd.clear();
    M5.Lcd.setCursor(0,0);
  }
  usbHost.task();

}

　
　　

　②atoms3lite_usb_host_keybord_to_i2c.ino
　◆USBキーボードから一文字入力が有れば、青色LEDを一瞬点灯し、
　　マスターからのリクエストで一文字I2C出力します。

//atoms3lite_usb_host_keybord_to_i2c.ino v20230706
//http://gijin77.blog.jp/archives/37426889.html
//USBキーボードをカードキーボードに変換(CardKB v1.1)

#include <FastLED.h>
#include <M5AtomS3.h>
#include "EspUsbHost.h"
#include <Wire.h>

#define SDA_PIN 2 
#define SCL_PIN 1

#define PIN_SW     41   // 本体釦 atoms3lite
#define PIN_LED    35   // 本体フルカラーLEDの使用端子（G21）
#define NUM_LEDS   1    // 本体フルカラーLEDの数

uint8_t keyPressed=0;
uint8_t KEY=0;
CRGB leds[NUM_LEDS];

class MyEspUsbHost : public EspUsbHost {
  void onKeyboardKey(uint8_t ascii, uint8_t keycode, uint8_t modifier) {
    KEY=ascii;keyPressed=1;
    leds[0] = CRGB(0, 0, 255); 
    FastLED.show();
    delay(100);
    leds[0] = CRGB(0, 0, 0); 
    FastLED.show();
  };
};

MyEspUsbHost usbHost;

void requestEvent() {
  if (keyPressed == 1) {
    Wire.write(KEY);
    keyPressed = 0;
  } else {
    Wire.write(0);
  }
}

void setup() {
  M5.begin(true, false, false, false);  // Init M5AtomS3
  FastLED.addLeds<WS2812B, PIN_LED, GRB>(leds, NUM_LEDS);
  for( int i=0;i<2;i++) {
    leds[0] = CRGB(255, 0, 0);   // 白色（赤, 緑, 青）※3色それぞれの明るさを0〜255で指定
    FastLED.show();
    delay(1000);
    leds[0] = CRGB(0, 255, 0);   // 白色（赤, 緑, 青）※3色それぞれの明るさを0〜255で指定
    FastLED.show();
    delay(1000);
    leds[0] = CRGB(0, 0, 255);   // 白色（赤, 緑, 青）※3色それぞれの明るさを0〜255で指定
    FastLED.show();
    delay(1000);
  }
  leds[0] = CRGB(0, 0, 0); 
  FastLED.show();
  
  usbHost.begin();
  usbHost.setHIDLocal(HID_LOCAL_Japan_Katakana);

  Wire.onRequest(requestEvent);
  Wire.setPins(SDA_PIN, SCL_PIN);
  Wire.begin(0x5f);

}

void loop() {
  usbHost.task();

}

　

◆CardKBの代わりをUSBキーボードで実現出来ました。

以上

　

３．確認環境　2022/07/03時点
　「atoms3_usb_host_keybord.ino」

//atoms3_usb_host_keybord.ino v20230703
//http://gijin77.blog.jp/archives/37402177.html
#include <M5AtomS3.h>
#include "EspUsbHost.h"

class MyEspUsbHost : public EspUsbHost {
  void onKeyboardKey(uint8_t ascii, uint8_t keycode, uint8_t modifier) {
    if (' ' <= ascii && ascii <= '~') {
      M5.Lcd.printf("%c", ascii);
    } else if (ascii == '\r') {
      M5.Lcd.println();
    }
  };
};

MyEspUsbHost usbHost;

void setup() {
  M5.begin(true, false, false, false);  // Init M5AtomS3
  M5.Lcd.setRotation( 3 );
  M5.Lcd.clear();
  M5.Lcd.setTextSize(2);
  M5.Lcd.println("EspUsbHostKeybord" );

  usbHost.begin();
  usbHost.setHIDLocal(HID_LOCAL_Japan_Katakana);
}

void loop() {
  M5.update();  // Read the press state of the key
  if (M5.Btn.wasReleased() || M5.Btn.pressedFor(1000)) {
    M5.Lcd.clear();
    M5.Lcd.setCursor(0,0);
  }
  usbHost.task();
}

　


　

 　④ATOMS3のピンアサイン
　

　

　①・STAMPS3を使いスーファミのコントローラをUSB化してPCで使ってみた
　②・AtomS3Liteを使いPSXコントローラをUSB化してPCで使ってみた
　➂・AtomS3Liteを使いスーファミのパチスロコントローラを専用USB化してみた

　

　


４．Arduino IDEでの書き込みについて
　①ボードの選択画面
　　「M5Stack Arduino」 -->「 STAMPS3」 を選択
　


　②USBコネクタをUSB-OTGにするための選択
　　「USB Mode」-->「USB OTG(TinyUSB)」を選択
　


　➂シリアルの選択
　　「COM6(ESP32S3 Dev Module」を選択
　　（ESP32S3のCOMを選択します。私の場合はCOM6でした。）
　

　④「→」アイコンをクリックして書き込みます。
　　一回OTGモードで書き込みますと、次に書き込むときは、
　　「G00」を押しながら電源を入れると書き込みモードとなります。

５．実際に北斗の拳のエミュレータの動作画面
　

６．これからやる事
　1.コントローラを仮付からコネクタに付け替える
　2.PS2のコントローラも変換できるようにする
　上記の為に、リサイクルショップでコントローラのソケットの
　部品取り用にジャンクのSFCとPS1をゲットしてきました。

　◆PSX版の変換器も作ってみました。下記ブログ内参照
　・AtomS3を使いPSXコントローラをUSB化してPCで使ってみた


　①スーパーファミコンのジャンク300円
　

　②プレイステーション１のジャンク100円
　

　➂ばらして、コネクタだけ取り出しました。
　

　④SFCのコネクタに配線しました。
　

　⑤M5STAMPS3で、プログラムの書き換えが便利になるように「RESET SW」と
　「G00 SW」を付けました。
　これまで、電源のoff/onでの操作でしたが、これによって電源は入れたままで
　SWの操作で出来るようになりました。
　「G00 SW」を押しながら「RESET SW」で、プログラムモードとなります。
　

　

　　◆M5Stack用の例です。

　◆順次変換します。

　　①本体SWで消音できます。
　　②LEDは、再生中青色表示で消音時滅灯、スリーブ時赤色となります。
　　➂起動時に音声合成によるIPアドレスを読み上げる様にしました。
　　　(2022/10/12)

　◆後さらに詳しくバッテリー情報を表示させてみました。
　下記、ブログ内記事も参照してみてください。
　・M5StickC Plus の バッテリー 情報 の 表示

３．バッテリーを交換しました。「2024/066/03(月)　追記」
　①容量は、少ないですが中に入るバッテリーが入手出来ましたので
　　交換しました。(120mAh-->100mAh)
（ショック：交換の際かと思われるのですが液晶が壊れてしまいました。）
　　詳しくは、下記ブログ内記事を参照して下さい。
　・M5StickC Plus の 液晶 が壊れたので交換してみた

　


以上

⑤詳しくは、下記で

　（その１は、抵抗2本とコンデンサ1個、ピンヘッダ）

#include <M5StickC.h>
#include <BLEDevice.h>
#include <BLEUtils.h>
#include <BLEScan.h>
#include <BLEAdvertisedDevice.h>

#define LED 10
int scanTime = 4; //BLEスキャン間隔
BLEScan* pBLEScan;

// 接触確認アプリのUUID
const char* uuid = "0000fd6f-0000-1000-8000-00805f9b34fb";
int deviceNum = 999;

class MyAdvertisedDeviceCallbacks: public BLEAdvertisedDeviceCallbacks {
    void onResult(BLEAdvertisedDevice advertisedDevice) {
       if(advertisedDevice.haveServiceUUID()){
            if(strncmp(advertisedDevice.getServiceUUID().toString().c_str(),uuid, 36) == 0){
                int rssi = advertisedDevice.getRSSI();
                Serial.print("RSSI: ");
                Serial.println(rssi);
                Serial.print("ADDR: ");
                Serial.println(advertisedDevice.getAddress().toString().c_str());
                Serial.println("Found!");
                deviceNum++;
            }
        }

    }
};

void disp(){    
  M5.Lcd.fillScreen(BLACK);
  M5.Lcd.setCursor(10,20);M5.Lcd.setTextSize(2);
  M5.Lcd.setTextColor(GREEN);M5.Lcd.print("COCOA");  
  if (deviceNum>9) M5.Lcd.setCursor(5,60); else M5.Lcd.setCursor(25,60);
  if (deviceNum>99) M5.Lcd.setTextSize(4); else M5.Lcd.setTextSize(6);
  M5.Lcd.setTextColor(WHITE);M5.Lcd.printf("%d", deviceNum);
  M5.Lcd.setCursor(0,120);M5.Lcd.setTextSize(1);
  M5.Lcd.setTextColor(CYAN);M5.Lcd.printf("BtnA=Restart");  
  M5.Lcd.setCursor(0,140);M5.Lcd.setTextSize(2);
  M5.Lcd.setTextColor(GREEN);M5.Lcd.printf("Bt%3.1fV\n", M5.Axp.GetBatVoltage());
}

void Task1(void *pvParameters) {
  // loop()内に書くとボタン圧下が取れないのでマルチスレッド化してある
  while(1) {
    deviceNum = 0;
    BLEScanResults foundDevices = pBLEScan->start(scanTime, false);
    disp();
    Serial.print("Devices found: ");
    Serial.println(deviceNum);
    Serial.println("Scan done!");
    pBLEScan->clearResults();   // delete results fromBLEScan buffer to release memory
  }
}

void setup() {
  M5.begin();
  Serial.begin(115200);
  Serial.println("Program Start...");
  pinMode(LED, OUTPUT);
  M5.Lcd.setRotation( 0 );
  M5.Lcd.fillScreen(GREEN);
  for(int i=0;i<3;i++) {
    digitalWrite(LED,LOW);delay(500);
    digitalWrite(LED,HIGH);delay(500);
  }
  disp();
  BLEDevice::init("");
  pBLEScan = BLEDevice::getScan(); //create new scan
  pBLEScan->setAdvertisedDeviceCallbacks(new MyAdvertisedDeviceCallbacks());
  pBLEScan->setActiveScan(true); //active scan uses more power, but get results faster
  pBLEScan->setInterval(100);
  pBLEScan->setWindow(99);  // less or equal setInterval value
  xTaskCreatePinnedToCore(Task1,"Task1", 4096, NULL, 3, NULL, 1);
}

void loop() {
  M5.update();
    if ( M5.BtnA.wasReleased() ) {
    // ボタンを押すとリスタート
      esp_restart();
    }
 }

＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊＊
＊４秒周期の数と電源on(リスタート)からの
　トータルの数を表示するように追加修正



◆経過時間追加



◆スケッチ例(cocoaM5StickC_2.ino)
次の項目を追加修正した。
①スタートからのトータル表示
　（マックアドレスをチェックして違うものだけカウント）
②ボタンＡでリスタート
③ボタンＢで電源ＯＦＦ
④スタートからの経過時間を表示

#include <M5StickC.h>
#include <BLEDevice.h>
#include <BLEUtils.h>
#include <BLEScan.h>
#include <BLEAdvertisedDevice.h>

#define LED 10
int scanTime = 4; //BLEスキャン間隔
BLEScan* pBLEScan;

// 接触確認アプリのUUID
const char* uuid = "0000fd6f-0000-1000-8000-00805f9b34fb";
int deviceNum = 0;
int cocoa = 999;
int skip_flg=0;
int hh=0;
int mm=0;
int ss=0;
unsigned long otime;

char  cocoa_buf[500][18] = {"01:23:45:57:89:ab","40:00:31:92:29:5a","01:23:45:57:89:ab","40:00:31:92:29:5a"};
char  c_buf[18] = "01:23:45:57:89:ab";

class MyAdvertisedDeviceCallbacks: public BLEAdvertisedDeviceCallbacks {
    void onResult(BLEAdvertisedDevice advertisedDevice) {
       if(advertisedDevice.haveServiceUUID()){
            if(strncmp(advertisedDevice.getServiceUUID().toString().c_str(),uuid, 36) == 0){
                int rssi = advertisedDevice.getRSSI();
                Serial.printf("RSSI: %d \n",rssi);
                strcpy(c_buf, advertisedDevice.getAddress().toString().c_str());
                Serial.printf("ADDR: %s \n",c_buf);
                Serial.println("Found!");
                cocoa++;
                skip_flg=0;
                for(int i=0;i<=deviceNum;i++) {
                  if (strcmp(cocoa_buf[i],c_buf)==0) {
                    skip_flg=1;
                    break;  
                  }
                }
                if (skip_flg==0) {
                  strcpy(cocoa_buf[deviceNum], c_buf);
                  deviceNum++;
                }
            }
        }

    }
};
void jikan(){
  otime = millis()/1000;
  ss=int(otime%60);
  mm=int((otime/60)%60);
  hh=int(otime/3600);
}
void disp(){    
  M5.Lcd.fillScreen(BLACK);
  M5.Lcd.setCursor(10,5);M5.Lcd.setTextSize(2);
  M5.Lcd.setTextColor(GREEN);M5.Lcd.print("COCOA");  
  if (cocoa>9) M5.Lcd.setCursor(5,40); else M5.Lcd.setCursor(25,40);
  if (cocoa>99) M5.Lcd.setTextSize(4); else M5.Lcd.setTextSize(6);
  M5.Lcd.setTextColor(WHITE);M5.Lcd.printf("%d", cocoa);
  M5.Lcd.setCursor(0,90);M5.Lcd.setTextSize(2);
  M5.Lcd.setTextColor(YELLOW);M5.Lcd.printf("T=%d", deviceNum);
  M5.Lcd.setCursor(0,110);M5.Lcd.setTextSize(1);jikan();
  M5.Lcd.setTextColor(GREEN);M5.Lcd.printf("Time=%02d:%02d:%02d",hh,mm,ss);  
  M5.Lcd.setCursor(0,120);M5.Lcd.setTextSize(1);
  M5.Lcd.setTextColor(CYAN);M5.Lcd.printf("BtnA=Restart");  
  M5.Lcd.setCursor(0,130);M5.Lcd.setTextSize(1);
  M5.Lcd.setTextColor(CYAN);M5.Lcd.printf("BtnB=PowerOff");  
  M5.Lcd.setCursor(0,146);M5.Lcd.setTextSize(2);
  M5.Lcd.setTextColor(GREEN);M5.Lcd.printf("Bt%3.1fV\n", M5.Axp.GetBatVoltage());
}

void Task1(void *pvParameters) {
  // loop()内に書くとボタン圧下が取れないのでマルチスレッド化してある
  while(1) {
    cocoa=0;
    BLEScanResults foundDevices = pBLEScan->start(scanTime, false);
    disp();
    Serial.printf("Devices found: %d Total: %d \n",cocoa,deviceNum);
    for (int i = 0; i < deviceNum; i++){
      Serial.printf("%03d=%s \n",i+1,cocoa_buf[i]);
    }
    Serial.println("Scan done!");   
    pBLEScan->clearResults();   // delete results fromBLEScan buffer to release memory
  }
}

void setup() {
  M5.begin();
  Serial.begin(115200);
  Serial.println("Program Start...");
  pinMode(LED, OUTPUT);
  M5.Lcd.setRotation( 0 );
  M5.Lcd.fillScreen(GREEN);
  for(int i=0;i<3;i++) {
    digitalWrite(LED,LOW);delay(500);
    digitalWrite(LED,HIGH);delay(500);
  }
  disp();
  BLEDevice::init("");
  pBLEScan = BLEDevice::getScan(); //create new scan
  pBLEScan->setAdvertisedDeviceCallbacks(new MyAdvertisedDeviceCallbacks());
  pBLEScan->setActiveScan(true); //active scan uses more power, but get results faster
  pBLEScan->setInterval(100);
  pBLEScan->setWindow(99);  // less or equal setInterval value
  xTaskCreatePinnedToCore(Task1,"Task1", 4096, NULL, 3, NULL, 1);
}

void loop() {
  M5.update();
  if ( M5.BtnB.wasReleased() ) {
    // ボタンを押すとパワーオフ
      M5.Axp.PowerOff();
  }
  if ( M5.BtnA.wasReleased() ) {
    // ボタンを押すとリスタート
      esp_restart();
  }
}

以前作っていた、バランスロボットをついに立たせることが出来ました。











ハードは、下記のサイトを参考にしました。
M5StickC バランスロボ

ソフトは、下記のサイトを参考にしました。
実質500円&100Stepで作る超簡単「 ゆるメカトロ的 M5StickC 倒立振子」

M5StickCはMadgwickフィルタで倒立振子の夢を見るか？


■スケッチ

#include <M5StickC.h>

//PIDパラメータ調整
#define OFFSET             90.0                    // 重心 後方-←90°→+前方
#define COEF_P             35.0                    // Propotional
#define COEF_I             1.5                     // Integral
#define COEF_D             50.0                    // Differential

//Motor
#define LED_PIN            10                      // 内蔵LED

#define MOTOR_R 0x65 //A0=low, A1=open
#define MOTOR_L 0x63 //A0=high, A1=open


//MPU6886 https://github.com/m5stack/M5StickC/blob/master/src/utility/MPU6886.h
#define MPU6886_AFS        M5.MPU6886.AFS_2G       // Ascale [g]      (±2,4,8,16)
#define MPU6886_GFS        M5.MPU6886.GFS_1000DPS  // Gscale [deg/s]  (±250,500,1000,200)
#define DPS                1000                    // Gscale [deg/s]
#define CALIBRATION_COUNT  1000

//Function
#define min(a,b)           ((a) < (b) ? (a) : (b))
#define max(a,b)           ((a) > (b) ? (a) : (b))

//キャリブレ結果
double offsetX;              //Gyro X
float  base_angle;           //Accl X
//ローテーション結果
float dpsX;                  //Gyro X
float angleX;                //Accl X
//積分
double gyro_angle_x = 0;
float  preInterval  = 0;

// I2Cドライバー
void drvMotor(byte adr, int16_t pwr) { //pwr -255 to 255
  byte dir, st;
  if (pwr < 0) dir = 2;
  else dir =1;
  byte ipower=(byte) (abs(pwr)/4); //
  if (ipower == 0) dir=3; //brake

  //constrain(x, a, b) xがa以上b以下のときはxがそのまま返ります。xがaより小さいときはa、bより大きいときはbが返ります。
  ipower = constrain (ipower, 0, 63);
  st = drv8830read(adr);
  if (st & 1) drv8830write(adr, 0, 0);
  drv8830write(adr, ipower, dir);
}

void drv8830write(byte adr, byte pwm, byte ctrl) {
  Wire.beginTransmission(adr);
  Wire.write(0);
  Wire.write(pwm*4+ctrl);
  Wire.endTransmission(true);
}

int drv8830read(byte adr) {
  Wire.beginTransmission(adr);
  Wire.write(1);
  Wire.endTransmission(false);
  Wire.requestFrom((int)adr, (int)1, (int)1);
  return Wire.read();
}


void setup() {
  //初期化
  M5.begin();
  M5.Lcd.setRotation(1);
  M5.Lcd.fillScreen(BLACK);
  M5.Lcd.setTextSize(2);
  M5.Lcd.setCursor(0, 0);
  M5.Lcd.println("<B-Robot v1>");
  //Motor設定
  pinMode(LED_PIN, OUTPUT);
  digitalWrite(LED_PIN, HIGH);

// I2C設定
  Wire.begin(0, 26, 400000); //SDA, SCL
//  Wire.setClock（50000）;
  drvMotor(MOTOR_R,0);
  drvMotor(MOTOR_L,0);

  //MPU設定
  M5.MPU6886.Init();
  M5.MPU6886.SetGyroFsr(MPU6886_GFS);
  M5.MPU6886.SetAccelFsr(MPU6886_AFS);
  delay(1000);

  //キャリブレーション
  calibration();
//  base_angle-=1.5;
//  offsetX+=0.6;

  M5.Lcd.setRotation(2);
  M5.Lcd.fillScreen(BLACK);
  M5.Lcd.setCursor(0, 140);
  M5.Lcd.printf("BT%3.1fV\n", M5.Axp.GetBatVoltage());
  face();
}

void loop() {
  static  int   Duty;
  float         power, powerP, powerD;
  static float  powerI = 0;
  double        angle;

  //MPUローテーション
  calcRotation();
  //モーター制御
  angle = angleX;
  M5.Lcd.setCursor(0, 0);
  if ((base_angle>=0)&&(base_angle<=1.0)) {
    M5.Lcd.setTextColor(GREEN);
  } else {
    M5.Lcd.setTextColor(RED);
  }
  M5.Lcd.printf(">%3.1f", base_angle);

  if ((angle - OFFSET > -20) && (angle - OFFSET < 20)) {    // ３０度以下だけモーター駆動
    powerP = (angle - OFFSET ) / 90;                        // angle=0～180  → -1～1
    powerI += powerP;
    powerD = dpsX / DPS;                                    // 角速度 → -1～1
    power = powerP * COEF_P + powerI * COEF_I + powerD * COEF_D;
    power = max(-1, min(1, power));                         // -1～1
    //モーター駆動
    Duty = (int)(255* power );
    drvMotor(MOTOR_R,Duty);
    drvMotor(MOTOR_L,Duty);
    digitalWrite(LED_PIN, HIGH);
  } else {                                                  // 転倒したら停止
    drvMotor(MOTOR_R,0);
    drvMotor(MOTOR_L,0);
    powerI = 0;
    digitalWrite(LED_PIN, LOW);
  }
  M5.update();
  if (M5.BtnA.wasReleased()) {
    M5.Lcd.fillScreen(GREEN);
    ESP.restart();
    while (true) ;
  }
}

//キャリブレーション関数
void calibration() {
  float raw_gyro_x, raw_gyro_y, raw_gyro_z;
  float raw_acc_x, raw_acc_y, raw_acc_z;
  float acc_x = 0, acc_y = 0, acc_z = 0;
  offsetX = 0;
  for (int i = 0; i < CALIBRATION_COUNT; i++) {
    M5.MPU6886.getGyroData(&raw_gyro_x, &raw_gyro_y, &raw_gyro_z);
    M5.MPU6886.getAccelData(&raw_acc_x, &raw_acc_y, &raw_acc_z);
    //ベースプログラムとM5StickCの組付け位置の違いによる座標系変換含む
    offsetX += -raw_gyro_x;
    acc_x   += -raw_acc_x;
    acc_y   +=  raw_acc_y;
    acc_z   += -raw_acc_z;
  }
  //gyro offset
  offsetX /= CALIBRATION_COUNT;
  //加速度から角度を算出
  acc_x   /= CALIBRATION_COUNT;
  acc_y   /= CALIBRATION_COUNT;
  acc_z   /= CALIBRATION_COUNT;
  base_angle = (atan2(acc_y, acc_z + abs(acc_x)) * 360 / 2.0 / PI) + 180;
}

//MPUローテーション関数
void calcRotation() {
  float raw_acc_x, raw_acc_y, raw_acc_z, raw_t, raw_gyro_x, raw_gyro_y, raw_gyro_z ;
  float acc_angle_x;
  M5.MPU6886.getGyroData(&raw_gyro_x, &raw_gyro_y, &raw_gyro_z);
  M5.MPU6886.getAccelData(&raw_acc_x, &raw_acc_y, &raw_acc_z);
  //ベースプログラムとM5StickCの組付け位置の違いによる座標系変換
  raw_gyro_x *= -1;
  raw_acc_x  *= -1;
  raw_acc_z  *= -1;
  //
  acc_angle_x = (atan2(raw_acc_y, raw_acc_z + abs(raw_acc_x)) * 360 / 2.0 / PI) + 180;
  dpsX = raw_gyro_x - offsetX;
  //積分
  float now_time = millis();
  float interval = now_time - preInterval;  //前回からの経過時間
  preInterval = now_time;
  gyro_angle_x += dpsX * (interval * 0.000999999);
  //相補フィルター
  angleX = (0.996 * gyro_angle_x) + (0.004 * acc_angle_x) + base_angle;
}

void face(){
 int x0=10;
 int y0=40;
 int w0=25;
 int h0=10;
 int col=TFT_ORANGE;
 M5.Lcd.fillRect(x0,y0,w0,h0,col);
 M5.Lcd.fillRect(x0+35,y0,w0,h0,col);
 M5.Lcd.fillCircle(x0+12,y0+25, 7,col);
 M5.Lcd.fillCircle(x0+12,y0+25, 5,BLACK);
 M5.Lcd.fillCircle(x0+48,y0+25, 7,col);
 M5.Lcd.fillCircle(x0+48,y0+25, 5,BLACK);
 M5.Lcd.fillTriangle(x0+30,y0+25, 30,90,50,90,col);
 M5.Lcd.fillRect(20,y0+60,40,15,col);
}

・M5StickC 搭載 web 操縦 リモコンカーを作ってみました。

前方衝突防止にAPDS9930近接センサーを搭載しました。
約10cmに壁があると停止又はバックするようにしました。
動画は、デモモードで自動で動いています。