◆ESP32-S3等が載っているボードを購入した時、購入時のファームウェアをバックアップ

　しておいて、いつでも元に戻せる状態にする為の、「esp32_flash_tool」を作ってみました。

１．準備

　①バッチファイルを保存する適当なフォルダを作成します。

　②書き込みツールの「esptool.exe」を探してそのフォルダにコピペします。

　　私の環境では、"C:\Users\yoshito\AppData\Local\Arduino15\packages\esp32\tools\

　　esptool_py\5.0.0\esptool.exe"をコピペしました。

２．下記のバッチファイルを「１-①」のフォルダへ保存します。
　＊エデッタで保存する時は、シフトJISで保存しないと、漢字表示が乱れます。
　　（保障無しの自己責任で）

:esp32_flash_tool.bat
@echo off
:: ============================================
:: ESP32 / ESP32-S3 Flash Backup & Restore Tool
:: V2025/08/24 By JK1VCK
:: 必要: esptool.exe (同じフォルダに置く)
:: ============================================

setlocal ENABLEDELAYEDEXPANSION

:: バッチファイルの第1引数をバックアップファイル名に利用
if "%~1"=="" (
    set BACKUP_FILE=factory_backup.bin
) else (
    set BACKUP_FILE=%~1
)

set BAUD=460800
set PORT=COM7
set CHIP=ESP32-S3
set FLASH_SIZE=16M
set FLASH_HEX=0x1000000

:MENU
echo.
echo =================================================
echo   ESP32 Flash Backup / Restore Tool
echo                        V2025/08/24 By JK1VCK
echo =================================================
echo   バックアップファイル = %BACKUP_FILE%
echo =================================================
echo   1. ポート選択 (現在: %PORT%)
echo   2. チップ選択 (現在: %CHIP%)
echo   3. フラッシュサイズ選択 (現在: %FLASH_SIZE%=%FLASH_HEX%)
echo   4. フラッシュ全体をバックアップ
echo   5. バックアップから復元
echo   6. 自動でチップ,フラッシュサイズ取得(flash-id)
echo   7. バックアップファイル名変更
echo   8. ディレクトリ表示(dir)
echo   9. 終了
echo =================================================
set /p choice="番号を入力してください: "

if "%choice%"=="1" goto PORT_SELECT
if "%choice%"=="2" goto CHIP_SELECT
if "%choice%"=="3" goto SIZE_SELECT
if "%choice%"=="4" goto BACKUP
if "%choice%"=="5" goto RESTORE
if "%choice%"=="6" goto AUTO_SIZE
if "%choice%"=="7" goto FILE_CHANGE
if "%choice%"=="8" goto FILE_DIR
if "%choice%"=="9" exit
goto MENU

:FILE_DIR
dir
pause
goto MENU

:FILE_CHANGE
set /p BACKUP_FILE=新しいバックアップファイル名を入力してください: 
goto MENU


:PORT_SELECT
echo.
echo [接続されている COM ポートを検索中...]
setlocal enabledelayedexpansion
set COUNT=0

rem PowerShellでCOMポート一覧を取得
for /f "tokens=*" %%a in ('powershell -Command "Get-CimInstance Win32_SerialPort | ForEach-Object { $_.DeviceID + ' - ' + $_.Name }"') do (
    set /a COUNT+=1
    set PORT!COUNT!=%%a
    echo !COUNT!: %%a
)
if %COUNT%==0 (
    echo *** COMポートが見つかりません ***
    pause
    exit /b
)
set /p SEL=番号を選択してください (1-%COUNT%):
for /f "tokens=1 delims= " %%b in ("!PORT%SEL%!") do set PORT=%%b
endlocal & set PORT=%PORT%
echo 選択されたポート = %PORT%
pause
goto MENU


:CHIP_SELECT
echo.
echo 対応チップ:
echo   1. ESP32
echo   2. ESP32-S2
echo   3. ESP32-S3
echo   4. ESP32-C3
echo   5. ESP32-P4
set /p ch="番号を入力してください: "
if "%ch%"=="1" set CHIP=ESP32
if "%ch%"=="2" set CHIP=ESP32-S2
if "%ch%"=="3" set CHIP=ESP32-S3
if "%ch%"=="4" set CHIP=ESP32-C3
if "%ch%"=="5" set CHIP=ESP32-P4
goto MENU

:SIZE_SELECT
echo.
echo 代表的なフラッシュサイズ:
echo   1. 2MB  (0x200000)
echo   2. 4MB  (0x400000)
echo   3. 8MB  (0x800000)
echo   4. 16MB (0x1000000)
set /p sz="番号を入力してください: "
if "%sz%"=="1" set FLASH_SIZE=2MB & set FLASH_HEX=0x200000
if "%sz%"=="2" set FLASH_SIZE=4MB & set FLASH_HEX=0x400000
if "%sz%"=="3" set FLASH_SIZE=8MB & set FLASH_HEX=0x800000
if "%sz%"=="4" set FLASH_SIZE=16MB & set FLASH_HEX=0x1000000
goto MENU

:AUTO_SIZE
echo.
echo [フラッシュサイズを自動取得中...]
for /f "tokens=*" %%i in ('esptool.exe --port %PORT% flash-id') do (
    echo %%i

    rem チップ名を取得
    echo %%i | find "Detecting chip type..." >nul
    if not errorlevel 1 (
        for /f "tokens=4" %%a in ("%%i") do set CHIP=%%a
    )

    rem フラッシュサイズを取得
    echo %%i | find "Detected flash size:" >nul
    if not errorlevel 1 (
        for /f "tokens=4" %%a in ("%%i") do set FLASH_SIZE=%%a
    )
)
echo 検出されたチップ名 = %CHIP%
echo 検出されたフラッシュサイズ = %FLASH_SIZE%

REM MB → HEX に変換
if "%FLASH_SIZE%"=="2MB"  set FLASH_HEX=0x200000
if "%FLASH_SIZE%"=="4MB"  set FLASH_HEX=0x400000
if "%FLASH_SIZE%"=="8MB"  set FLASH_HEX=0x800000
if "%FLASH_SIZE%"=="16MB" set FLASH_HEX=0x1000000
if "%FLASH_SIZE%"=="32MB" set FLASH_HEX=0x2000000
if "%FLASH_SIZE%"=="64MB" set FLASH_HEX=0x4000000

echo 書き込みに使用するサイズ: %FLASH_SIZE% = %FLASH_HEX%
echo.
pause
goto MENU

:BACKUP
if "%PORT%"=="" (
    echo [エラー] ポートが未設定です
    pause
    goto MENU
)
if "%CHIP%"=="" (
    echo [エラー] チップが未設定です
    pause
    goto MENU
)
if "%FLASH_SIZE%"=="" (
    echo [エラー] フラッシュサイズが未設定です
    pause
    goto MENU
)
echo.
echo [バックアップ開始] → %BACKUP_FILE%
esptool.exe --chip %CHIP% --port %PORT% --baud %BAUD% read-flash 0 %FLASH_HEX% %BACKUP_FILE%
echo.
echo [バックアップ完了] → %BACKUP_FILE%
pause
goto MENU

:RESTORE
if not exist %BACKUP_FILE% (
    echo [エラー] バックアップファイル %BACKUP_FILE% が存在しません
    pause
    goto MENU
)
echo.
echo [復元開始] ← %BACKUP_FILE%
esptool.exe --chip %CHIP% --port %PORT% --baud %BAUD% write-flash 0 %BACKUP_FILE%
echo.
echo [復元完了]
pause
goto MENU

　

３．バッチファイルを起動します。

　◆コマンドとして下記の９個が選択できます。

　　1. ポート選択 (現在: COM7)

　　2. チップ選択 (現在: ESP32-S3)

　　3. フラッシュサイズ選択 (現在: 16M=0x1000000)

　　4. フラッシュ全体をバックアップ

　　5. バックアップから復元

　　6. 自動でチップ,フラッシュサイズ取得(flash-id)

　　7. バックアップファイル名変更

　　8. ディレクトリ表示(dir)

　　9. 終了

　＊初期状態では、バックアップファイル名は「factory_backup.bin」となっています。

　　コマンド「7」で変更できます。　
　＊あるいは、バッチコマンドに引数として、ファイル名を指定して実行すると
　　それが、バックアップファイル名となります。

　

　①まず最初にボードを接続してシリアルポートを設定します。

　

　②チップを選択します。

　

　➂フラッシュサイズを選択します。

　
　
　ここで、②➂を自動で取得するには、コマンド「6」を実行します。

　

　④バックアップを実行します。

　⑤復元を実行します。

◆これにて、いつでも元に戻せる状態に出来ます。

以上

ブログトップへ

◆MicroSDに保存してあるバイナリファイルを選択して起動できる

　「Launcher」なるソフトがあることが分かり、早速試してみました。

　CYD-2432W328は、インストールして問題なく動きました。

　しかし、JC3248W535Cは、表示がおかしく動きませんでした。

　ESP32-4848S040Cは、サポートすら無いボードでした。

　サイトを見るとソースファイルが公開されていましたので、表題の２ボードを

　動くように修正して何とか動くようになりました

　

　

１．「Launcher」について

　①下記サイトに行き、自分の持っているボードが有れば選択してインストールして
　　みて下さい。

　　「Launcher」

　
　

　②「Launcher」について詳しい使い方などは、下記「macsbug」氏のサイトを
　　参照して下さい。

　　macsbug CYD Launcher

２．私の場合、不具合や、そこに無いボードでしたのでソースを修正することにしました。

　①下記サイトよりソースファイル一式(zip)をダウンロードします。

　　bmorcelli/Launcher
　　

　①まず、表示がおかしいJC3248W535C(CYD-3248W535)を調べてみました。

　

５．JC3248W535Cボードでのオリジナルとの比較です。
　◆比較用のソフトは、「WinMerge」を使っています。
　　下記よりダウンロード出来ます。
　　WinMerge 日本語版
　
　◆フォルダ構成（下記6個のファイルを修正しています。）
　root---platfomeio.ini
           +-src---display.cpp
           l        +-main.cpp
           l        +-tft.h
           +-boards---CYD-2432S028---interfase.cpp
                                                       +-platfomeio.ini
　①ルートフォルダ
　

　②platfomeio.iniの修正箇所
　　＊元のボードをコメントアウトし、CYD-3248W535C を追加しました。
　　＊ライブラリのバージョンを最新にししました。
　

　➂srcフォルダ
　

　④display.cppの修正箇所
　　＊Ard_eSPI を Arduino_Canvas から継承してコンストラクタを定義しました。
　

　⑤main.cppの修正箇所
　　＊デバッグ用に追加しました。（多分なくても良い）
　

　⑥tft.hの修正箇所
　　＊Ard_eSPI を Arduino_Canvas から継承してコンストラクタを定義しました。
　

　⑦boardフォルダ
　

　⑧interface.cppの修正箇所
　　＊タッチ操作でワンタッチでツータッチになったのでその部分を
　　　全部書き換えしました。
　

　⑨platfomeio.iniの修正箇所
　　＊大元で指定しているのでコメントアウトしましました。
　　＊MicroSDカードのピン番号を追加しましました。
　
　
　➉以上6個のファイルをzipにしたものです。オリジナルと交換して再ビルド
　　すれば、JC3248W535C 用の「Launcher」が出来ると思います。
　　（保障無しの自己責任で）　　CYD-3248W535C.zip

６．ESP32-4848S040Cボードでのオリジナルとの比較です。
　
　　
　①こちらも同様ですので、以下に修正ファイルのzipファイルを示します。
　　（保障無しの自己責任で）　　CYD-4848S040C.zip

７．JC3248W535Cでの実行例
　①立ち上がり時の画面（LAUNCHERをタップ）

　

　②メニュー画面（SDを選択後「SEL」をタップ）
　

　➂SD内ファイル表示画面
　　（実行したいbinファイルを「NEXT又はPREV」で選択して「SEL」をタップ）
　

　④ＳＤファイル操作画面
　　（実行したいコマンドを「NEXT又はPREV」で選択して「SEL」をタップ）
　　 ◆ここではInstallを選択

　

　⑤インストール中
　

　⑥インストールされたbinファイルが実行されます。
　

８．開発環境を構築するのが大変という方に下記二つの.binファイルをzipにしたものを
　　ダウンロードして下さい。

　　　（保障無しの自己責任で）　　CYD-bin.zip
　
　　①書き込みツールは、下記よりダウンロード後解凍し

　　「flash_download_tool_3.9.7.exe」を実行して、ボードへ書き込みます。
　　　Flash Download Tool (バージョン3.9.7) 

　　②ボードをPCへ接続します。　

ブログトップへ