//esp32p4_GXF_wifi_Scan.ino
//V1 /2025/04/18 By JK1VCK <Arduino_GFX_Library.h>使用
//blog URL:https://gijin77.blog.jp/archives/44343378.html
//JC1060P470 esp32p4 Flash Size:"16MB" Partition Scheme:16M Flash(2MB APP..) 
//           PSRAM : en UPload Mode : USB-OTG...

#include <WiFi.h>
#include <Arduino_GFX_Library.h>

//***************************************************************************
#define GFX_DEV_DEVICE JC1060P470
#define LED      26
#define LEDON    LOW
#define LEDOFF   HIGH
#define GFX_BL 23 // default backlight pin, you may replace DF_GFX_BL to actual backlight pin
#define DSI_PANEL
Arduino_ESP32DSIPanel *dsipanel = new Arduino_ESP32DSIPanel(
    40 /* hsync_pulse_width */, 160 /* hsync_back_porch */, 160 /* hsync_front_porch */,
    10 /* vsync_pulse_width */, 23 /*vsync_back_porch  */, 12 /* vsync_front_porch */,
    48000000 /* prefer_speed */);
Arduino_DSI_Display *gfx = new Arduino_DSI_Display(
    1024 /* width */, 600 /* height */, dsipanel, 0 /* rotation */, true /* auto_flush */,
    27 /* RST */, jd9165_init_operations, sizeof(jd9165_init_operations) / sizeof(lcd_init_cmd_t));
#define C6_RESET  54  // ESP32-C6のリセットピン
//***************************************************************************

void setup() {
  Serial.begin(115200);
  delay(1000);
  // ESP32-C6をリセット
  pinMode(C6_RESET, OUTPUT);
  digitalWrite(C6_RESET, LOW);
  delay(100);
  digitalWrite(C6_RESET, HIGH);
  delay(2000);  // ESP32-C6の起動待機

  pinMode(GFX_BL, OUTPUT);digitalWrite(GFX_BL, HIGH); //バックライトON  
  gfx->begin();
  gfx->setRotation(0);gfx->fillScreen(BLACK);
  gfx->setCursor(0,2);gfx->setTextColor(GREEN);gfx->setTextSize(3);
  gfx->drawRect(0,0,gfx->width()-1,gfx->height()-1,YELLOW);//枠表示
  //digitalWrite(GFX_BL, HIGH); //バックライトON  
  Serial.println("WiFi Scan / Arduino_GFX_Library Start");  
  gfx->println("WiFi Scan / Arduino_GFX_Library Start");  
  // Set WiFi to station mode and disconnect from an AP if it was previously connected.
  WiFi.mode(WIFI_STA);
  WiFi.disconnect();
  delay(100);
  Serial.println("Setup done");
  gfx->println("Setup done");
}

void loop() {
  gfx->setTextSize(3);gfx->setTextColor(GREEN);
  Serial.println("WiFi Scan start");gfx->println("WiFi Scan start");
  // WiFi.scanNetworks will return the number of networks found.
  int n = WiFi.scanNetworks();
  Serial.println("WiFi Scan done");gfx->println("WiFi Scan done");
  if (n == 0) {
    Serial.println("no networks found");gfx->println("no networks found");
  } else {
    Serial.printf("\n %d networks found\n",n);gfx->printf("\n %d networks found\n",n);
    gfx->setTextSize(2);gfx->setTextColor(CYAN);
    Serial.println(" No| SSID                             | MAC アドレス       | RSSI | CH | Encryption");
    gfx->println(" No| SSID                             | MAC address        | RSSI | CH | Encryption");
    for (int i = 0; i < n; ++i) {
      // Print SSID and RSSI for each network found
      gfx->setTextColor(ORANGE);
      Serial.printf("%2d | %-32.32s | %-18.18s | %4ld | %2ld | ", i + 1,WiFi.SSID(i).c_str(),WiFi.BSSIDstr(i).c_str(),WiFi.RSSI(i),WiFi.channel(i));
      gfx->printf("%2d | %-32.32s | %-18.18s | %4ld | %2ld | ", i + 1,WiFi.SSID(i).c_str(),WiFi.BSSIDstr(i).c_str(),WiFi.RSSI(i),WiFi.channel(i));      switch (WiFi.encryptionType(i)) {
        case WIFI_AUTH_OPEN:            Serial.print("open");     gfx->print("open"); break;
        case WIFI_AUTH_WEP:             Serial.print("WEP");      gfx->print("WEP");break;
        case WIFI_AUTH_WPA_PSK:         Serial.print("WPA");      gfx->print("WPA"); break;
        case WIFI_AUTH_WPA2_PSK:        Serial.print("WPA2");     gfx->print("WPA2"); break;
        case WIFI_AUTH_WPA_WPA2_PSK:    Serial.print("WPA+WPA2"); gfx->print("WPA+WPA2"); break;
        case WIFI_AUTH_WPA2_ENTERPRISE: Serial.print("WPA2-EAP"); gfx->print("WPA2-EAP"); break;
        case WIFI_AUTH_WPA3_PSK:        Serial.print("WPA3");     gfx->print("WPA3"); break;
        case WIFI_AUTH_WPA2_WPA3_PSK:   Serial.print("WPA2+WPA3");gfx->print("WPA2+WPA3"); break;;
        case WIFI_AUTH_WAPI_PSK:        Serial.print("WAPI");     gfx->print("WAPI"); break;
        default:                        Serial.print("unknown");  gfx->print("unknown");
      }                                                                 
      Serial.println();gfx->println();
      delay(10);
    }
  }
  Serial.println("");gfx->println("");
  // Delete the scan result to free memory for code below.
  WiFi.scanDelete();
  // Wait a bit before scanning again.
  delay(20000);
  gfx->fillScreen(BLACK);gfx->setCursor(0,2);
  gfx->drawRect(0,0,gfx->width()-1,gfx->height()-1,YELLOW);//枠表示
}

３．実行中の様子
　　20秒毎にスキャンを繰り返します。
　

４．アクセスポイントへの接続試験用スケッチ
　①ssidとpasswordを自分用に修正して下さい。

//esp32p4_wifi.ino

#include <WiFi.h>

#define C6_RESET  54  // ESP32-C6のリセットピン
// Wi-Fi設定
const char* ssid = "IO_Net_2G";
const char* password = "1234567890";

void setup() {
  Serial.begin(115200);
  delay(1000);

  // ESP32-C6をリセット
  pinMode(C6_RESET, OUTPUT);
  digitalWrite(C6_RESET, LOW);
  delay(100);
  digitalWrite(C6_RESET, HIGH);
  delay(2000);  // ESP32-C6の起動待機

  // Wi-Fi接続開始
  WiFi.begin(ssid, password);
  Serial.print("Wi-Fi接続中...");

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("\nWi-Fi接続成功！");
  Serial.print("IPアドレス: ");
  Serial.println(WiFi.localIP());
}

void loop() {
  // 例: HTTPリクエスト送信
  if (WiFi.status() == WL_CONNECTED) {
    Serial.println("Wi-Fi接続済み");
  } else {
    Serial.println("Wi-Fi切断中");
  }
  delay(5000);
}

　②実行中のシリアル出力
　

５．WiFi事例でNHKのニュース表示してみました。
　下記ブログ内記事を参照して下さい。
・JC1060P470C（ESP32P4 ESP32C6 搭載) ArduinoIDE環境でNHK RSSニュース表示してみた


以上

　

//get_news.ino
//V2025/04/15 by JK1VCK
//blog URL:https://gijin77.blog.jp/archives/44314639.html

#include <WiFi.h>
#include <WiFiClientSecure.h>

//Yahooニュース: https://news.yahoo.co.jp/rss/topics/top-picks.xml
//NHKニュース: https://www3.nhk.or.jp/rss/news/cat0.xml
//ITmedia: https://rss.itmedia.co.jp/rss/2.0/news_bursts.xml
//livedoor: http://news.livedoor.com/topics/rss/top.xml

//ニュースサイトを選択する
#define    yahoo    //Yahooニュース:
//#define    nhk      //NHKニュース
//#define    itmedia  //ITmedia
//#define    livedoor //livedoor:

#if defined(yahoo)
  const char* host = "news.yahoo.co.jp";
  const char* path = "/rss/topics/top-picks.xml";
#elif defined(nhk)
  const char* host = "www3.nhk.or.jp";
  const char* path = "/rss/news/cat0.xml";
#elif defined(itmedia)
  const char* host = "rss.itmedia.co.jp";
  const char* path = "/rss/2.0/news_bursts.xml";
#elif defined(livedoor)
  const char* host = "news.livedoor.com";
  const char* path = "/topics/rss/top.xml";
#endif
const int httpsPort = 443;

const char* ssid = "IO_Net_2G";  //Your SSID
const char* password = "1234567890";  //Your PASSWORD

void setup() {
  Serial.begin(115200);
  delay(1000);

  WiFi.begin(ssid, password);
  Serial.print("WiFi connecting");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" connected!");
  Serial.println(WiFi.localIP());

  WiFiClientSecure client;
  client.setInsecure();  // 一時的に証明書チェックを無効化

  Serial.printf("Connecting to %s...\n", host);
  if (!client.connect(host, httpsPort)) {
    Serial.println("Connection failed!");
    return;
  }

  client.printf("GET %s HTTP/1.1\r\n", path);
  client.printf("Host: %s\r\n", host);
  client.println("User-Agent: ESP32RSSClient");
  //client.println("Connection: close\r\n"); //これを書くとNHKがすぐに切断する
  client.println();
  Serial.println("=== RSS Feed Start ===");
 
bool isBody = false;
unsigned long timeout = millis();

  while ((millis() - timeout) < 2000) {  // タイムアウトを2秒にする
    while (client.available()) {
      String line = client.readStringUntil('\n');
      line.trim();
      if (!isBody && line.length() == 0) {
        isBody = true;
        continue;
      }
      if (isBody) {
        Serial.println(line);
      }
      timeout = millis();  // データが来たらタイムアウトリセット
    }
    if (!client.connected()) break;
  }
  client.stop();  // ←ここで明示的に切るのはOK
  Serial.println("=== RSS Feed End ===");
}

void loop() {
}

//get_news_v2.ino
//V2025/04/21 by JK1VCK
//blog URL:https://gijin77.blog.jp/archives/44314639.html

#include <WiFi.h>
#include <WiFiClientSecure.h>

//Yahooニュース: https://news.yahoo.co.jp/rss/topics/top-picks.xml
//NHKニュース: https://www3.nhk.or.jp/rss/news/cat0.xml
//ITmedia: https://rss.itmedia.co.jp/rss/2.0/news_bursts.xml
//livedoor: http://news.livedoor.com/topics/rss/top.xml

//ニュースサイトを選択する
//#define    yahoo    //Yahooニュース:
#define    nhk      //NHKニュース
//#define    itmedia  //ITmedia
//#define    livedoor //livedoor:

#if defined(yahoo)
  const char* host = "news.yahoo.co.jp";
  const char* path = "/rss/topics/top-picks.xml";
#elif defined(nhk)
  const char* host = "www3.nhk.or.jp";
  const char* path = "/rss/news/cat0.xml";
#elif defined(itmedia)
  const char* host = "rss.itmedia.co.jp";
  const char* path = "/rss/2.0/news_bursts.xml";
#elif defined(livedoor)
  const char* host = "news.livedoor.com";
  const char* path = "/topics/rss/top.xml";
#endif
const int httpsPort = 443;

const char* ssid = "IO_Net_2G";
const char* password = "1234567890";

void setup() {
  Serial.begin(115200);
  delay(1000);

  WiFi.begin(ssid, password);
  Serial.print("WiFi connecting");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println(" connected!");
  Serial.println(WiFi.localIP());

  WiFiClientSecure client;
  client.setInsecure();  // 一時的に証明書チェックを無効化

  Serial.printf("Connecting to %s...\n", host);
  if (!client.connect(host, httpsPort)) {
    Serial.println("Connection failed!");
    return;
  }

  client.printf("GET %s HTTP/1.1\r\n", path);
  client.printf("Host: %s\r\n", host);
  client.println("User-Agent: ESP32RSSClient");
  //client.println("Connection: close\r\n"); //これを書くとNHKがすぐに切断する
  client.println();
  Serial.println("=== RSS Feed Start ===");
 
bool isBody = false;
unsigned long timeout = millis();
String titleTag = "<title>";
String titleEnd = "</title>";

  while ((millis() - timeout) < 2000) {  // タイムアウトを2秒にする
    while (client.available()) {
      String line = client.readStringUntil('\n');
      line.trim();
      if (!isBody && line.length() == 0) {
        isBody = true;
        continue;
      }
      if (isBody) {
        if (line.startsWith(titleTag)) {
          String title = line.substring(titleTag.length(), line.indexOf(titleEnd));
          Serial.println("Title: " + title);
           // LCDに表示したい処理へ
        }
        //Serial.println(line);
      }
      timeout = millis();  // データが来たらタイムアウトリセット
    }
    if (!client.connected()) break;
  }
  client.stop();  // ←ここで明示的に切るのはOK
  Serial.println("=== RSS Feed End ===");
}

void loop() {
}

　


以上