下記写真
　

//EspUsbHostKeyboard.ino
//V2024/04/21 by JK1VCK
//blog URL:http://gijin77.blog.jp/archives/40553229.html

#include "EspUsbHost.h"

#define BUFFER_MAX 64 // リングバッファのサイズ
uint8_t chr_buf[BUFFER_MAX]; // 文字リングバッファ用の配列
uint8_t cod_buf[BUFFER_MAX]; // コードリングバッファ用の配列
uint8_t sht_buf[BUFFER_MAX]; // シフトリングバッファ用の配列

uint8_t head = 0; // 読み込み位置
uint8_t tail = 0; // 書き込み位置
uint8_t KEY=0;
uint8_t K_CODE=0;
uint8_t K_SHIFT=0;

//***************************************************
class MyEspUsbHost : public EspUsbHost {
  void onKeyboardKey(uint8_t ascii, uint8_t keycode, uint8_t modifier) {
    chr_buf[tail] = ascii;    // 文字を書き込む
    cod_buf[tail] = keycode;  // コードを書き込む
    sht_buf[tail] = modifier; // シフトを書き込む
    tail = (tail + 1) % BUFFER_MAX; // tailを次の位置に進める
    if (tail == head) head = (head + 1) % BUFFER_MAX; // バッファフル時は頭を進める
  };
};

MyEspUsbHost usbHost;

void key_input_task(void* arg) { //別タスクで実行
  while(1){
    usbHost.task();
    delay(1);
  }
}

uint8_t get_keyboard() {
  uint8_t c=0;
  if (head != tail) { // バッファが空でなければ
    KEY=chr_buf[head]; // 文字を読み出す
    K_CODE=cod_buf[head]; // 文字を読み出す
    K_SHIFT=sht_buf[head]; // 文字を読み出す
    head = (head + 1) % BUFFER_MAX; // headを次の位置に進める
    c=K_CODE;
  }
  return(c);
}

void setup() {
  Serial.begin(115200);
  delay(500);

  usbHost.begin();
  usbHost.setHIDLocal(HID_LOCAL_Japan_Katakana);
  Serial.println("ESP32-S3 Keyboard Test Start");
  usbHost.begin();
  usbHost.setHIDLocal(HID_LOCAL_Japan_Katakana);
  xTaskCreate(key_input_task, "key_input_task", 2048, NULL, 1, NULL);

}

void loop() {
  uint8_t c=get_keyboard();
  if (c!=0){
    Serial.printf("IN=%02d OUT=%02d ", tail,head);
    Serial.printf("KEY=%02x K_CODE=%02x K_SHIFT=%02x char=%c\n", KEY,K_CODE,K_SHIFT,KEY);
  }
  delay(1000); //わざと一秒遅らせる
}

６．書き込み＆実行
　①ボード情報
　

　②実行結果

　

以上

//atoms3_efont.ino
//V2024/04/17 by JK1VCK
//blog URL:http://gijin77.blog.jp/archives/40506691.html

#include <M5AtomS3.h>
#include "efontEnableJaMini.h"
//#include "efontEnableJa.h"
#include "efont.h"

//#define EFONT_DEBUG
#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels

//efont 文字列を表示する
//**********************************************************************************************
void printEfont(int16_t x,int16_t y,int16_t txtsize,uint16_t color,uint16_t bgcolor,char *str) {
  int posX = x;
  int posY = y;
  int16_t textsize = txtsize;
  uint16_t textcolor = color;
  uint16_t textbgcolor = bgcolor;
  byte font[32];
  while( *str != 0x00 ){
    // 改行処理
    if( *str == '\n' ){
      // 改行
      posY += 16 * textsize;
      posX += 16 * textsize;
      str++;
      continue;
    }
    // フォント取得
    uint16_t strUTF16;
    str = efontUFT8toUTF16( &strUTF16, str );
    getefontData( font, strUTF16 );
    // 文字横幅
    int width = 16 * textsize;
    if( strUTF16 < 0x0100 ){
      // 半角
      width = 8 * textsize;
    }

#ifdef EFONT_DEBUG
    Serial.printf( "str : U+%04X\n", strUTF16 );
#endif

    // 背景塗りつぶし
    M5.Lcd.fillRect(posX, posY, width, 16 * textsize, textbgcolor);
    // 取得フォントの確認
    for (uint8_t row = 0; row < 16; row++) {
      word fontdata = font[row*2] * 256 + font[row*2+1];
      for (uint8_t col = 0; col < 16; col++) {

#ifdef EFONT_DEBUG
        Serial.write( ( (0x8000 >> col) & fontdata ) ? "#" : " " );
#endif

        if( (0x8000 >> col) & fontdata ){
          int drawX = posX + col * textsize;
          int drawY = posY + row * textsize;
          if( textsize == 1 ){
            M5.Lcd.drawPixel(drawX, drawY, textcolor);
          } else {
            M5.Lcd.fillRect(drawX, drawY, textsize, textsize, textcolor);
          }
        }
      }

#ifdef EFONT_DEBUG
        Serial.write( "\n" );
#endif

    }
    // 描画カーソルを進める
    posX += width;
    // 折返し処理
    if( SCREEN_WIDTH <= posX ){ 
      posX = 0;
      posY += 16 * textsize;
    }
  }
  // カーソルを更新
  M5.Lcd.setCursor(posX, posY);
}

void setup() {
auto cfg = M5.config();
  M5.begin(cfg);
  Serial.begin(115200); // シリアル通信初期設定
  delay(1000);        // シリアル接続待ち
  Serial.println("AtomS3 eFont Test!"); // シリアル出力
  M5.Lcd.setRotation( 3 );
  M5.Lcd.clear();
}

void loop() {
  M5.Lcd.clear();
  printEfont(1,10,1,GREEN, BLACK,(char *)"1倍角 こんにちは");
  printEfont(1,28,1,GREEN, BLACK,(char *)"ABCDEFGHIJKLMNOPQRSTUVWXYZ123456");
  delay(5000);
  M5.Lcd.clear();  
  printEfont(1,1,2,GREEN, BLACK,(char *)"2倍角 こんにちは");
  delay(5000);
  M5.Lcd.clear();  
  printEfont(1,1,3,GREEN, BLACK,(char *)"3倍角 こんにちは");
  delay(5000);
}

２．実行画面