//ch32v_oled_demo.ino
//modified v2024/02/26 by JK1VCK
//blog URL:http://gijin77.blog.jp/archives/39932667.html
#include <Wire.h>
#include <Arduino.h>
#include <oled.h>
//
//SSD1306は128x64表示可能であるがch32v003のRAMが2kしかないのでバッファを1024バイト確保できない
//よって128x32に制限される 
//幅は、enum tWidth { W_96=96, W_128=128 };高さは、  enum tHeight { H_16=16, H_32=32, H_64=64 };
//コントローラは  enum tDisplayCtrl { CTRL_SSD1306, CTRL_SH1106 };と定義されている
//OLED(uint8_t sda_pin, uint8_t scl_pin, uint8_t reset_pin=NO_RESET_PIN, tWidth width=W_128, tHeight height=H_32,
//  tDisplayCtrl displayCtrl=CTRL_SSD1306, uint8_t i2c_address=0x3C);
OLED oled=OLED(PC1,PC2,NO_RESET_PIN,OLED::W_128,OLED::H_32,OLED::CTRL_SSD1306,0x3c);

static const uint8_t bitmap[] = { 
    1,2,4,8,16,32,64,128,128,128,192,192,128,128,128,64,32,16,8,4,2,1, // 最初のページ (垂直 8 ビット、22 列)
    255,255,255,255,15,15,15,15,15,15,15,15,15,15,15,15,15,15,255,255,255,255 // 2 ページ目 (垂直 8 ビット、22 列)
};

void setup(){
  delay(1000);
  oled.begin();   
}

void loop(){
  oled.clear();    // 通常のサイズでテキストを描画する
  oled.draw_string(2,0,"123456789012345678901"); //6x8フォントの為(128/6)21文字表示出来る
  for (int y=8;y<32;y+=8) {
    oled.draw_string(2,y,"CH32V003 OLED SSD1306");
  }
  oled.display();   // 外側のエッジにピクセルを描画します
  oled.draw_pixel(0,0);
  oled.draw_pixel(127,0);
  oled.draw_pixel(127,31);
  oled.draw_pixel(0,31);    
  oled.display();
  delay(1000);      // 中空の円を描く
  for (uint_least8_t radius=3; radius<62; radius+=3){ 
    delay(50);
    oled.draw_circle(64,16,radius);
    if (radius>15) {
        oled.draw_circle(64,16,radius-15,OLED::SOLID,OLED::BLACK);
    }
    oled.display();
  }
  delay(500);    // 実線の円を描く
  oled.draw_circle(36,16,14,OLED::SOLID);
  oled.display();
  delay(500);
  oled.draw_circle(36,16,7,OLED::SOLID,OLED::BLACK);
  oled.display();
  delay(500);     // 長方形を描く
  oled.draw_rectangle(64,0,98,31);    
  oled.display();
  delay(500);
  oled.draw_rectangle(69,5,93,26,OLED::SOLID);
  oled.display();
  delay(1000);    // スクロールアップする
  oled.scroll_up(32,20);
  oled.draw_string(4,2,"Hello");    // 通常のサイズでテキストを描画する
  oled.display();
  delay(1000);    // 線を引く
  oled.draw_line(4,10,34,10);
  oled.display();    
  delay(1000);    // テキストを2倍のサイズで描画する
  oled.draw_string_P(16,15,PSTR("World!"),OLED::DOUBLE_SIZE);
  oled.display();
  delay(1000);    // 十字を描く
  oled.draw_line(16,31,88,15);
  oled.draw_line(16,15,88,31);
  oled.display();
  delay(1000);    // 生のビットマップを描画する
  oled.draw_bitmap_P(100,8,22,16,bitmap);
  oled.display();
  delay(1000);    // スクロールのデモンストレーション
  oled.set_scrolling(OLED::HORIZONTAL_RIGHT);
  delay(3000);
  oled.set_scrolling(OLED::HORIZONTAL_LEFT);
  delay(3000);
  oled.set_scrolling(OLED::NO_SCROLLING);

  oled.display();   // スクロール後に再描画して元の画像を取得します
  delay(1000);      // OLEDをフラッシュする
  for (int i=0; i<10; i++) {
      oled.set_invert(true);delay(200);
      oled.set_invert(false);delay(200);
  }
  uint8_t cont[]={128,64,32,16,8,4,2,1,2,4,8,16,32,64,128,255,128};
  for(int i=0;i<17;i++) {    // コントラスト値を表示する
    contrast(cont[i]); 
  }
  delay(500);
  oled.clear();
}
void contrast(int value){
  char buffer[4];
  oled.clear();  
  oled.draw_string(0,0,"Contrast:");
  itoa(value,buffer,10);
  oled.draw_string(64,0,buffer);
  oled.draw_rectangle(0,20,value/2,31,OLED::SOLID);
  oled.display();
  oled.set_contrast(value);
  delay(500);
}

//CH32V_IR_Decoder.ino
//v1 2024/02/23 
//blog URL:http://gijin77.blog.jp/archives/39900522.html
//PD7 リセットピン L=リセット

#include "Arduino.h"
#define IR_PIN    PD4
#define LED       PC0
//                           POWER     ,↑        ,↓         ,→        ,←        ,MENU
const uint32_t IR_DATA[] = { 0x61D648B7,0x61D6D827,0x61D658A7,0x61D6609F,0x61D620DF,0x61D6A05F };
const size_t   IR_CT     = (sizeof(IR_DATA) / sizeof(IR_DATA[0]));
const uint8_t  LED_PIN[] = { PD3,PC7,PC6,PC5,PC4,PC3 };//POW,↑,↓,→,←,MENU
const size_t   LED_CT= (sizeof(LED_PIN) / sizeof(LED_PIN[0]));

bool f_entry=false;  // エントリフラグ
uint32_t tt0;
uint32_t tmp_data;
uint32_t ir_data;

uint8_t  pulsecounter=0;             // 受信ビットカウンタ
uint32_t t0=0;                       // 割り込み間隔用
uint32_t ir_value=0;                 // IR コード
bool     ir_begin=false;             // 解析スタートフラグ
uint32_t t_buf[40];                  // デバッグ用バッファ
//*************************************************************************
//          I S R _ I R 
//*************************************************************************
// 信号がL->Hへ変化するたびに IR受光器から受信し割り込み。
// データの間隔は 640 または 1640 us秒です。 同期パルスは 3400 us以上です。
// 最後の 32 レベルの変更がリモコンコードです。
// 解析はＮＥＣフォーマットのみ
//*************************************************************************
void isr_IR() {
uint32_t t1, intval;       // 現在の時刻と最後の変更からの間隔
  digitalWrite(LED, LOW);
  t1=micros();             // 現在時刻を取得する
  intval=t1 - t0;          // 間隔を計算
  t0=t1;                   // 次の比較のために保存する
  if(intval > 4000) {      // コードのシーケンスを開始するか? 3500<t<5500
    pulsecounter=0;        // カウンタをリセットする
    ir_value=0;
    ir_begin=true;
    digitalWrite(LED, HIGH);
    return;
  }
  if(ir_begin==false) {
    digitalWrite(LED, HIGH);
    return;
  }
  if (intval>2000) intval=intval-2000; //CH32Vでランダムに2ms加算される時があるので調整
  t_buf[pulsecounter]=intval;     // デバッグ用に割り込み間隔を保存
  if(intval < 1000){              // ショートパルス? 400<t<750
    ir_value=(ir_value << 1) + 0; // 「0」をセットしシフトする
    pulsecounter++;               // 受信ビット数をカウントアップする
  } else if(intval > 1500){       // ロングパルス? 1400<t<1900
    ir_value=(ir_value << 1) + 1; // 「1」をセットしシフトする
    pulsecounter++;               // 受信ビット数をカウントアップする
  }
  if(pulsecounter==32){
    ir_begin=false;
    ir_data=ir_value;    //解析終了データをセーブ
  }
  digitalWrite(LED, HIGH);
}

void setup(){
  Serial.begin(115200);
  delay(3000);
  Serial.println();Serial.println("<IR Start>");
  pinMode(LED, OUTPUT);digitalWrite(LED,HIGH);
  for (size_t i = 0; i < LED_CT; i++) {
    pinMode(LED_PIN[i], OUTPUT);
    digitalWrite(LED_PIN[i], HIGH); //LED Off
  }
//CH32V003 割り込み処理 IR_PINの立上りにより割り込みを発生させ、「isr_IR」にて処理します。
//EXTI_Trigger_Falling 立下り EXTI_Trigger_Rising  立上り EXTI_Trigger_Rising_Falling 両方
  attachInterrupt(digitalPinToInterrupt(IR_PIN), GPIO_Mode_IN_FLOATING, isr_IR, EXTI_Mode_Interrupt, EXTI_Trigger_Rising);
}

void loop(){
  ir_loop();
}

void ir_loop(){
  if(f_entry == false) {tt0 = millis(); f_entry = true;}
  if((tt0 + 49 > millis()) && (tt0 <= millis())) return;   // 50ms待ちます（オーバーフローの場合は除く）
  f_entry = false;
  if(tmp_data == ir_data) return;         // 前と同じだったらリターン
  tmp_data = ir_data;
  Serial.printf("ir_dat: %X\n",ir_data ); //IRデータを表示
  for (int i=0;i<32;i++){
    if (!(i%4)) Serial.println();
    Serial.printf("i=%d %lu\n",i,t_buf[i]);
  }
  for (size_t i = 0; i < IR_CT; i++) {
    if(ir_data==IR_DATA[i]) {digitalWrite(LED_PIN[i], LOW);} //LED On
  }
  delay(500);
  for (size_t i = 0; i < LED_CT; i++) {
    digitalWrite(LED_PIN[i], HIGH); //LED Off
  }
}

void sw_Isr() {
    digitalWrite(PD0, LOW);
    Serial.println("(LED ON)");
}

void setup() {
  Serial.begin(115200);
  Serial.println("Program Start...");
  pinMode(PD0, OUTPUT);
  attachInterrupt(digitalPinToInterrupt(PD4), GPIO_Mode_IN_FLOATING, sw_Isr, EXTI_Mode_Interrupt, EXTI_Trigger_Falling);
}

void loop() {
  delay(5000);
  digitalWrite(PD0, HIGH);
  Serial.println("<LED Off>");
}