//ATTiny85_IR_TX.ino V20230802 by yh
//http://gijin77.blog.jp/archives/37720136.html
#include <Arduino.h>
#include <avr/wdt.h> // wdt_disable()を使うため
#include <avr/sleep.h>

#define OUTPUT_PIN  (_BV(4) | _BV(1)) // 4:インジケータ、1:赤外線LED (PWM)

// 外部割り込みを受け取るピン 
const uint8_t wakeUpPin = 2; //リモコン用 

// 赤外線LEDを38kHzで点灯させる（1番ピン）
//コンパイル時の設定
//Clock Souce "1M internal"
//FUSEビット出荷時のFUSE内容(E:FF, H:DF, L:62)CLKDIV8は有効。
void pwm_out(int microseconds) {
  PORTB |= _BV(4); // インジケータ点灯：digitalWrite(4, HIGH)と同じ
  // タイマー(TC0)を設定
  OCR0A = 25;  // TOP value :  38kHz --> 26.3us.
  OCR0B = 6;  //  H period  : 6.4us.
  TCCR0A = B00100011; // COM0A: 00, COM0B: 10, WGM01-00: 11
  TCCR0B = B00001001; // FOC:00, WGM02:1, CS02-01: 001 (system clock x1)
  TCNT0 = OCR0A;
  delayMicroseconds(microseconds); // 指定マイクロ秒だけ点灯
  // タイマー(TC0)をリセット
  TCCR0A = 0; // タイマー(TC0)リセット
  TCCR0B = 0; // タイマー(TC0)リセット
  PORTB &= ~_BV(4); // インジケータ消灯：digitalWrite(4, LOW)と同じ
}

void setup() {
// 初期化
  cli();             // noInterrupts();の中身（割り込み停止）
  DDRB = OUTPUT_PIN; // B010010000　pinMode(PB1, OUTPUT),pinMode(PB4, OUTPUT)
  PORTB = 0;         // B00000000　PB1もPB4もLOW
  ACSR |= 0x80;      // アナログコンパレータ禁止
  ADCSRA &= 0x7f;    // disable ADC
  wdt_disable();     // ウォッチドッグタイマを停止
  TIMSK = 0;         // disable Timer0/1 overflow interrupt.
  sei();             // Interrupts();の中身（割り込み許可）
  pinMode(wakeUpPin, INPUT_PULLUP); // 外部割り込みを受け取るピンを入力モードに設定
  delayMS(1000); // 1秒待つ処理）
  attachInterrupt(digitalPinToInterrupt(wakeUpPin), wakeUp, LOW); // 外部割り込みを有効にする
  set_sleep_mode(SLEEP_MODE_PWR_DOWN); // スリープモードをPWR_DOWNに設定
  sleep_enable(); // スリープモードを有効にする
  sleep_mode();   // スリープモードに入る
}

void loop(){ //何もしない
}

void wakeUp() {  // 外部割り込みがトリガーされたときの処理をここに書きます
  noInterrupts();
  send_nec(0x594220DF);
  interrupts();
  sleep_enable(); // スリープモードを有効にする
  sleep_mode();   // スリープモードに入る
}

void delayMS(uint16_t ms){
  for (int i = 0; i < ms; i++) { // msミリ秒待つ処理）
    delayMicroseconds(1000); // 1ミリ秒待つ
  }  
}

void send_nec(uint32_t irdata){ //ＮＥＣフォーマット用 38kHz
 pwm_out(9000);                //  リーダーコード ON:9000us OFF:4500us
 delayMicroseconds(4500); 
 for(int i=0;i<32;i++) {
    if (irdata & 0x80000000){   //データ1   ON:560us OFF:1690us
      pwm_out(560);
      delayMicroseconds(1690);
    }else{                     //データ0   ON:560us OFF:565us
      pwm_out(560);
      delayMicroseconds(565);
    }
    irdata=irdata<<1;
 }
 pwm_out(560);                //ストップビット ON:560us 
 delayMicroseconds(9000*2);   // 赤外線OFF 18000us
}