https://bleis-tift.hatenablog.com/entry/syntax-is-important

Twitterでこんなつぶやきをしました。

プログラミング言語としてのSQL(select)とか、プログラミング言語としてのXSLTとかやると、構文大事って実感持ててオススメ。オススメはしない。
— ぐるぐる系SQL (@bleis) 2021年4月24日

が、ちょっと違う感じに受け取られたかな、と思ったので補足します。

「プログラミング言語としての」とは

つぶやきの中でいちいち「プログラミング言語としての」と書いたのは、「普通の」SQLや「普通の」XSLTとは違って、ということを明示したかったからです。

普通はSQLは問合せのための言語だし、XSLTはXMLを変換するための言語*1であって、JavaやC#などのプログラミング言語と同じようなものと見ている人はほぼいないでしょう。ただ、ちょっとしたテクニックを知っていると、これらを使って「普通の」プログラミング言語でやるような処理が書けてしまうのです。

XSLTでプログラミング

XSLTにはループや分岐が組み込まれているので、手続き型プログラミングであればどうとでもなります。なりますが、それでは面白くないのでループを封印してみましょう。

ループを使わないXSLTプログラミング

XSLTでは template を関数とみなすことで、ループを使わなくても再帰呼び出しが使えます。あとは高階関数が使えればざっくり関数プログラミング的なものが出来ますね。詳しい説明はそのアイディアを形にした人が書いたドキュメントに譲るとして、そのテクニックを使うことでFizzBuzzが range 関数と map 関数と fizzbuzz 関数を組み合わせることで書けてしまいます。

クリックでXSLTによるFizzBuzzコードを展開

<?xml version="1.0" encoding="UTF-8"?>
<!-- 最近のXSLT事情がよくわからないけど、Saxonで動作確認(ファイル名: style.xsl) -->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xs="http://www.w3.org/2001/XMLSchema"
                xmlns:fizzbuzz="fizzbuzz"
                version="3.0">

  <xsl:output method="text"/>

  <!-- fromからtoまでの数列を作る関数 -->
  <xsl:template name="range" as="xs:integer *">
    <xsl:param name="from" as="xs:integer"/>
    <xsl:param name="to" as="xs:integer"/>

    <xsl:choose>
      <xsl:when test="$from &lt;= $to">
        <xsl:sequence select="$from"/>
        <xsl:call-template name="range">
          <xsl:with-param name="from" select="$from + 1"/>
          <xsl:with-param name="to" select="$to"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <!-- シーケンスのmap関数 -->
  <xsl:template name="map">
    <xsl:param name="sequence"/>
    <xsl:param name="f"/>

    <xsl:choose>
      <xsl:when test="empty($sequence)">
      </xsl:when>
      <xsl:otherwise>
        <xsl:variable name="v">
          <xsl:apply-templates select="$f">
            <xsl:with-param name="arg0" select="$sequence[1]"/>
          </xsl:apply-templates>
        </xsl:variable>
        <xsl:sequence select="$v"/>
        <xsl:call-template name="map">
          <xsl:with-param name="sequence" select="$sequence[position() > 1]"/>
          <xsl:with-param name="f" select="$f"/>
        </xsl:call-template>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <fizzbuzz:fizzbuzz/>

  <!-- 数値を与えるとFizzBuzzかFizzかBuzzか数値自身を返す関数 -->
  <xsl:template name="fizzbuzz" match="*[namespace-uri()='fizzbuzz']">
    <xsl:param name="arg0" />

    <xsl:variable name="n" select="number($arg0)"/>
    <xsl:choose>
      <xsl:when test="$n mod 15 = 0">
        <xsl:value-of select="'FizzBuzz&#x0A;'"/>
      </xsl:when>
      <xsl:when test="$n mod 5 = 0">
        <xsl:value-of select="'Buzz&#x0A;'"/>
      </xsl:when>
      <xsl:when test="$n mod 3 = 0">
        <xsl:value-of select="'Fizz&#x0A;'"/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$n"/>
        <xsl:value-of select="'&#x0A;'"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <!-- エントリーポイント -->
  <xsl:template match="/">
    <xsl:variable name="from" select="input/from"/>
    <xsl:variable name="to" select="input/to"/>

    <xsl:variable name="xs" as="xs:integer *">
      <xsl:call-template name="range">
        <xsl:with-param name="from" select="$from"/>
        <xsl:with-param name="to" select="$to"/>
      </xsl:call-template>
    </xsl:variable>

    <xsl:call-template name="map">
      <xsl:with-param name="sequence" select="$xs"/>
      <xsl:with-param name="f" select="document('')/*/fizzbuzz:*[1]"/>
    </xsl:call-template>
  </xsl:template>
</xsl:stylesheet>

<?xml version="1.0" encoding="UTF-8"?>
<!-- 入力ファイル(ファイル名: input.xml) -->
<input>
  <from>1</from>
  <to>100</to>
</input>

# 実行方法
$ saxon -s:input.xml -xsl:style.xsl -o:output.txt

長いので折り畳みましたが、これと同じようなことを F# で書くとこうなります。

let rec range from ``to`` =
  if from <= ``to`` then from :: range (from + 1) ``to`` 
  else []

let rec map f = function
| [] -> []
| x::xs -> f x :: map f xs

let fizzbuzz n =
  if n % 15 = 0 then "FizzBuzz\n"
  elif n % 5 = 0 then "Buzz\n"
  elif n % 3 = 0 then "Fizz\n"
  else string n + "\n"

let xs = range 1 100
xs |> map fizzbuzz |> List.iter (printf "%s")

大体機械的に対応は取れると思います。

SQLでプログラミング

SQLは再帰クエリーによって再帰が書けます。しかし、XSLTとは違い関数に対応させられるようなものが(SELECT文の範疇では)ありませんし、高階関数など夢のまた夢です。そのため、SQLでのプログラミングはXSLTよりも困難です。

ただ、再帰クエリーでも使う WITH を「入力固定の関数」のようなものとみなすことで、ある程度の構造化は可能です。

-- 最近PostgreSQLを使っているのでPostgreSQL想定
WITH RECURSIVE range_ (n_) AS (
  SELECT 1
  UNION ALL
  SELECT n_ + 1 FROM range_ WHERE n_ < 100
)
, fizzbuzz_ (n_, result_) AS (
  SELECT
      n_
    , CASE
        WHEN n_ % 15 = 0 THEN 'FizzBuzz'
        WHEN n_ % 5 = 0 THEN 'Buzz'
        WHEN n_ % 3 = 0 THEN 'Fizz'
        ELSE CAST(n_ AS varchar)
      END
  FROM
    range_
)
SELECT * FROM fizzbuzz_;

さらに複雑なことがしたい場合、空白区切りなどの文字列をリストと見立てて操作することでよりいろいろなことができるようになります*2。

構文って大事

こんな感じで、XSLTでプログラミングしようとすると大量のノイズで本来書きたい処理はタグの中に埋もれてしまいますし、 SQL(select)でプログラミングしようとするとそもそも関数からしてないので考え方からして変えないといけません(そのための例としてはFizzBuzzは小さすぎたかも)。 SQLで複雑なやつだと、 SQL で数式を評価 (完全版 + α) - ぐるぐる～あたりがオススメです。数式評価だけど、演算子の優先順位を設定可能な完全に頭おかしいやつです。

ということで、他の人にはあまりオススメできない、オススメの構文のありがたみが体感できる方法でした。制約された環境であれこれ考えるのが好きな人であればあるいは・・・

*1:言語？ツール？

*2:配列型やJSONを使うという選択肢もあるけどそれだとツマラナイ